LADA โปรแกรม ลดโมเสค ที่มาแรงแซง Javplayer ต้องลอง

[อบเชยเฉยๆ]

60fps ของผมเคยกินอะไรเท่าไหร่มันก็กินเท่าเดิม แต่นานขึ้น เพราะมันแค่เพิ่มจำนวนภาพเฉยๆอะ

[RTKnet]

File FHD FPS60  Preset Q25P7

Spec Ryzen5900X
RTX4070ti 12GB
Ram32

ถ้า 4K น่าจะเป็น 10ชม++

ผมกำลังมีแพลนจะซื้อคอมใหม่ แต่ช่วงนี้ ราคา RAM และ อะไรต่างๆ ปรับราคาขึ้นเยอะมาก ซึ่ง ซีรีย์ 70ti ก็คือสเปกในฝันของผม งาน Frame rate 60 นี่มัน x2 เรื่องของเวลาจริงๆ

ขอทราบเป็นข้อมูลครับว่า ไฟล์หนังความยาว 3 ชั่วโมงนี้ fps 60 แบบนี้ จบงานแล้ว ใช้เวลาไปทั้งหมดกี่ชั่วโมงครับ กิน ram การ์ดจอเต็มไหมครับ พวกอุณหภูมิองศา การกินไฟระหว่างทำประมาณกี่วัตต์ครับ 

ไฟล์ 3ชม 60FPS ปกติ จบงานอยู่ราวๆ 4ชม ครึ่ง - 5ชม ครึ่ง ครับ
ตอนใช้แบบโปรแกรมฯ ปกติ เคยรัน 4K30FPS อยู่ 7ชม

ram เครื่องไม่ถึง 15-16GB
แต่ GPU 90% ตลอดครับ อุณหภูมิอยู่แค่ 45-52 (การ์ด 3พัดลม)

มันจะไวกว่านี้ ถ้าไม่เปิดทำอย่างอื่นด้วย
ผมดู youtube ไปด้วย

ตอนนี้อยากได้ คำสั่ง shutdown หลังจบงาน รบกวนด้วยครับ

[YEDKUNG]

File FHD FPS60  Preset Q25P7

Spec Ryzen5900X
RTX4070ti 12GB
Ram32

ถ้า 4K น่าจะเป็น 10ชม++

ผมกำลังมีแพลนจะซื้อคอมใหม่ แต่ช่วงนี้ ราคา RAM และ อะไรต่างๆ ปรับราคาขึ้นเยอะมาก ซึ่ง ซีรีย์ 70ti ก็คือสเปกในฝันของผม งาน Frame rate 60 นี่มัน x2 เรื่องของเวลาจริงๆ

ขอทราบเป็นข้อมูลครับว่า ไฟล์หนังความยาว 3 ชั่วโมงนี้ fps 60 แบบนี้ จบงานแล้ว ใช้เวลาไปทั้งหมดกี่ชั่วโมงครับ กิน ram การ์ดจอเต็มไหมครับ พวกอุณหภูมิองศา การกินไฟระหว่างทำประมาณกี่วัตต์ครับ 

ไฟล์ 3ชม 60FPS ปกติ จบงานอยู่ราวๆ 4ชม ครึ่ง - 5ชม ครึ่ง ครับ
ตอนใช้แบบโปรแกรมฯ ปกติ เคยรัน 4K30FPS อยู่ 7ชม

ram เครื่องไม่ถึง 15-16GB
แต่ GPU 90% ตลอดครับ อุณหภูมิอยู่แค่ 45-52 (การ์ด 3พัดลม)

มันจะไวกว่านี้ ถ้าไม่เปิดทำอย่างอื่นด้วย
ผมดู youtube ไปด้วย

ตอนนี้อยากได้ คำสั่ง shutdown หลังจบงาน รบกวนด้วยครับ

@echo off
cd /d "%~dp0"
setlocal EnableDelayedExpansion
chcp 65001 >nul

if not exist "Output" mkdir "Output"

echo =================================================================
echo   LADA v ULTIMATE (By YedKung)
echo   Mode: H.264 / CQ 24 / Preset P7 (High Quality)
echo   Status: Ready...
echo =================================================================

for %%F in ("input\*.mp4") do (
    call :ProcessFile "%%~fF"
)

echo.
echo =================================================================
echo   ALL JOBS FINISHED.
echo   SHUTTING DOWN IN 60 SECONDS...
echo =================================================================

:: >>> สั่งปิดเครื่องตรงนี้ (นับถอยหลัง 60 วินาที) <<<
shutdown /s /t 60

:: จบการทำงาน (เอา pause ออก เพื่อให้มันปิดได้เลย)
exit

:: -------------------------------------------------------------------
::  โซนทำงาน
:: -------------------------------------------------------------------
:ProcessFile
set "fullpath=%~1"
set "filename=%~nx1"
set "basename=%~n1"
set "target=Output\%basename%_UncenByYedkung.mp4"

if exist "%target%" (
    echo [SKIP] Already Done: "%filename%"
    exit /b
)

:: --- 1. อ่านข้อมูลไฟล์ (คงฟีเจอร์เดิมไว้ครบถ้วน) ---
set "f_width=0"
set "f_height=0"
set "f_duration=Unknown"
set "f_codec=Unknown"
set "f_frames=Unknown"
set "f_fps=Unknown"

:: อ่านความกว้าง
for /f "tokens=*" %%a in ('ffprobe -v error -select_streams v:0 -show_entries stream^=width -of default^=noprint_wrappers^=1:nokey^=1 "%fullpath%" 2^>nul') do set "f_width=%%a"
:: อ่านความสูง
for /f "tokens=*" %%b in ('ffprobe -v error -select_streams v:0 -show_entries stream^=height -of default^=noprint_wrappers^=1:nokey^=1 "%fullpath%" 2^>nul') do set "f_height=%%b"
:: อ่านความยาว
for /f "tokens=*" %%c in ('ffprobe -v error -show_entries format^=duration -of default^=noprint_wrappers^=1:nokey^=1 -sexagesimal "%fullpath%" 2^>nul') do set "f_duration=%%c"
:: อ่าน Codec
for /f "tokens=*" %%d in ('ffprobe -v error -select_streams v:0 -show_entries stream^=codec_name -of default^=noprint_wrappers^=1:nokey^=1 "%fullpath%" 2^>nul') do set "f_codec=%%d"
:: อ่านจำนวนเฟรม
for /f "tokens=*" %%e in ('ffprobe -v error -select_streams v:0 -show_entries stream^=nb_frames -of default^=noprint_wrappers^=1:nokey^=1 "%fullpath%" 2^>nul') do set "f_frames=%%e"
:: อ่าน FPS
for /f "tokens=*" %%f in ('ffprobe -v error -select_streams v:0 -show_entries stream^=r_frame_rate -of default^=noprint_wrappers^=1:nokey^=1 "%fullpath%" 2^>nul') do set "f_fps=%%f"

echo.
echo ---------------------------------------------------
echo  FILE DETAILS:
echo  Name       : %filename%
echo  Codec      : %f_codec%
echo  Resolution : %f_width% x %f_height%
echo  Frames     : %f_frames% (%f_fps% fps)
echo  Length     : %f_duration%
echo ---------------------------------------------------

:: จำเวลาเริ่ม
set "t_start=%time: =0%"
echo  Start      : %t_start%
echo  Status     : Processing (HQ Mode / P7)...

:: --- 2. สั่งรันโปรแกรม (อัปเกรดสูตรใหม่ตรงนี้!) ---
:: แก้ไข: เปลี่ยน p4 -> p7 และเพิ่ม -tune hq -b_ref_mode 2 ตามสูตร Dev
lada-cli.exe ^
  --input "%fullpath%" ^
  --output "%target%" ^
  --device cuda:0 ^
  --fp16 ^
  --max-clip-length 180 ^
  --mp4-fast-start ^
  --encoder h264_nvenc ^
  --encoder-options "-cq 24 -preset p7 -tune hq -b_ref_mode 2 -rc vbr -rc-lookahead 32 -spatial-aq 1 -temporal-aq 1" ^
  --mosaic-detection-model "_internal\model_weights\lada_mosaic_detection_model_v4_fast.pt" ^
  --mosaic-restoration-model "_internal\model_weights\lada_mosaic_restoration_model_generic_v1.2.pth"

:: จำเวลาจบ
set "t_end=%time: =0%"

:: --- 3. คำนวณเวลา ---
call :CalcDuration "%t_start%" "%t_end%" _duration

echo  Finish     : %t_end%
echo  Used       : %_duration%
echo ---------------------------------------------------
exit /b

:: -------------------------------------------------------------------
::  โซนเครื่องคิดเลข
:: -------------------------------------------------------------------
:CalcDuration
set "sTime=%~1"
set "eTime=%~2"
for /f "tokens=1-4 delims=:.," %%a in ("%sTime%") do set /a "t1=((1%%a-100)*360000)+((1%%b-100)*6000)+((1%%c-100)*100)+(1%%d-100)"
for /f "tokens=1-4 delims=:.," %%a in ("%eTime%") do set /a "t2=((1%%a-100)*360000)+((1%%b-100)*6000)+((1%%c-100)*100)+(1%%d-100)"
set /a "diff=t2-t1"
if %diff% lss 0 set /a "diff+=8640000"
set /a "hh=diff/360000"
set /a "rem=diff%%360000"
set /a "mm=rem/6000"
set /a "rem=rem%%6000"
set /a "ss=rem/100"
set /a "cc=rem%%100"
if %hh% lss 10 set "hh=0%hh%"
if %mm% lss 10 set "mm=0%mm%"
if %ss% lss 10 set "ss=0%ss%"
if %cc% lss 10 set "cc=0%cc%"
set "%~3=%hh%:%mm%:%ss%.%cc%"
exit /b

ถ้าสั่งรันไปแล้ว จะไม่ปิดเครื่องแล้ว  เปลี่ยนใจ
ให้เปิด cmd ขึ้นมาใหม่ แล้วพิมพ์ว่า ​พิมพ์ shutdown /a  ครับ

[RTKnet]

ตอนนี้เจอปัญหาแบบนี้ หลายไฟล์แล้ว เฉพาะที่เป็นไฟล์ FHD 60FPS

Speed ตกเหลืออยู่แค่ 10.x  ตอนท้ายๆ
มาเปิดเช็คงานแล้ว หลายช่วง หน่วงๆ จนน่ารำคาญ

จะแก้ไขยังไงดี ลดค่า P ?
ปรับให้ใช้แรมเครื่องมากกว่านี้ ? use (15-16 /32GB)

[kongav]

วิธีทำให้ขนาดไฟล์ไม่ลดลงต้องตั้งค่ายังไงหรือครับ ผมทำแล้วมันลดบิตเรตลงมาเยอะมากจากต้นฉบับ

[YEDKUNG]

วิธีทำให้ขนาดไฟล์ไม่ลดลงต้องตั้งค่ายังไงหรือครับ ผมทำแล้วมันลดบิตเรตลงมาเยอะมากจากต้นฉบับ

ใน LADA ตั้งแต่เวอชั่น 10 ขึ้นไป custom Code ได้ครับ

ลองปรับตามนี้ครับ ถ้ารู้สึกว่า bite rate ต่ำกว่าต้นฉบับ ให้ปรับ -cq ต่ำลงดูครับลองเอาสัก 18 ให้เห็นผลไปเลย แล้วค่อยเพิ่มถ้าคิดว่ามันเวอร์เกิน สำหรับผม -cq 24 กำลังดี ทดลองกับไฟล์ 10 วิ ช่วงที่มีฉาก censor ก็ได้ครับ

(สำหรับต้นฉนับที่เป็น Code h264 นะครับ 265 ไม่เคยลอง)


Code ที่ผมใช้

โค๊ด:

-cq 24 -preset p7 -tune hq -multipass qres -spatial_aq 1 -temporal_aq 1 -b_ref_mode 2 -profile high -rc vbr

[kongav]

วิธีทำให้ขนาดไฟล์ไม่ลดลงต้องตั้งค่ายังไงหรือครับ ผมทำแล้วมันลดบิตเรตลงมาเยอะมากจากต้นฉบับ

ใน LADA ตั้งแต่เวอชั่น 10 ขึ้นไป custom Code ได้ครับ

ลองปรับตามนี้ครับ ถ้ารู้สึกว่า bite rate ต่ำกว่าต้นฉบับ ให้ปรับ -cq ต่ำลงดูครับลองเอาสัก 18 ให้เห็นผลไปเลย แล้วค่อยเพิ่มถ้าคิดว่ามันเวอร์เกิน สำหรับผม -cq 24 กำลังดี ทดลองกับไฟล์ 10 วิ ช่วงที่มีฉาก censor ก็ได้ครับ

(สำหรับต้นฉนับที่เป็น Code h264 นะครับ 265 ไม่เคยลอง)


Code ที่ผมใช้

โค๊ด:

-cq 24 -preset p7 -tune hq -multipass qres -spatial_aq 1 -temporal_aq 1 -b_ref_mode 2 -profile high -rc vbr

ขอบคุณนะค้าบเดี๋ยวลองดู

[kongav]

สอบถามอีกเรื่องครับท่าน
ถ้าทำเยอะๆอะไรจะพังก่อนหรือครับ ระหว่างการ์ดจอกับ cpu

ของผม i5 12th 12400f การ์ด gtx 1080 ti แรม 16 ยังพอทำอันสั้นๆที่ตัดมาได้แต่นานเหมือนกัน

หรือว่าสเปคแค่นี้ไม่ควรทำจะดีกว่าไหมครับ

[ZEUS]

สอบถามอีกเรื่องครับท่าน
ถ้าทำเยอะๆอะไรจะพังก่อนหรือครับ ระหว่างการ์ดจอกับ cpu

ของผม i5 12th 12400f การ์ด gtx 1080 ti แรม 16 ยังพอทำอันสั้นๆที่ตัดมาได้แต่นานเหมือนกัน

หรือว่าสเปคแค่นี้ไม่ควรทำจะดีกว่าไหมครับ

ถ้านานมากโหลด javfree ก็สะดวกดีนะครับ ผมเห็นทำออกมาเรื่อยๆเรื่องเก่าๆก็มี

ลองสังเกตุดูครับ ตอนรันเครื่องมันทำงานหนักขนาดไหน พัดลมเร่งดังมากไหม

ที่จริง cpu gpu  มันทนมากนะครับ งานแค่นี้ไม่เท่าไหร่ มันจะพังก็พวกความร้อน ซึ่งก็เกิดจากใช้งานหนักต่อเนื่องเป็นเวลานาน
แต่ อดีตราชาอย่าง 1080ti ก็นานมากแล้วระวังหน่อยก็ดีครับ มันไม่พังง่ายๆหรอก แต่ช่วงนี้ปัญหาเรื่อง chip ขาดตลาดเซฟหน่อยก็ดี

[kongav]

สอบถามอีกเรื่องครับท่าน
ถ้าทำเยอะๆอะไรจะพังก่อนหรือครับ ระหว่างการ์ดจอกับ cpu

ของผม i5 12th 12400f การ์ด gtx 1080 ti แรม 16 ยังพอทำอันสั้นๆที่ตัดมาได้แต่นานเหมือนกัน

หรือว่าสเปคแค่นี้ไม่ควรทำจะดีกว่าไหมครับ

ถ้านานมากโหลด javfree ก็สะดวกดีนะครับ ผมเห็นทำออกมาเรื่อยๆเรื่องเก่าๆก็มี

ลองสังเกตุดูครับ ตอนรันเครื่องมันทำงานหนักขนาดไหน พัดลมเร่งดังมากไหม

ที่จริง cpu gpu  มันทนมากนะครับ งานแค่นี้ไม่เท่าไหร่ มันจะพังก็พวกความร้อน ซึ่งก็เกิดจากใช้งานหนักต่อเนื่องเป็นเวลานาน
แต่ อดีตราชาอย่าง 1080ti ก็นานมากแล้วระวังหน่อยก็ดีครับ มันไม่พังง่ายๆหรอก แต่ช่วงนี้ปัญหาเรื่อง chip ขาดตลาดเซฟหน่อยก็ดี

ขอบคุณครับท่าน